E-posta bombardımanı etkilerini azaltma

E-posta bombardımanı, saldırganın alıcının gelen kutusunu taşırmak amacıyla belirli bir adrese veya bilgisayar ağına çok miktarda e-posta gönderdiği bir çevrim içi saldırı türüdür.

Bu saldırının giderek daha yaygın hale gelen bir türü, kullanıcı e-posta kutusunun kayıt onay e-postalarıyla bombardımana tutulmasından oluşmaktadır.

Proton Mail, istenmeyen iletilerin gelen kutusuna ulaşmasını önlemek için istenmeyen süzgeci sunmaktadır. Ancak, e-posta bombardımanı durumlarında, istenmeyen etkinlik genellikle meşru kayıt formlarından kaynaklanır ve bu da bazı durumlarda istenmeyen süzgecini etkisiz kılabilir. Bu gibi durumlar için daha gelişmiş bir Sieve süzgeci kullanabilirsiniz. Bu makalede, gelen kutunuza bir Sieve süzgeci ekleme adımları açıklanacaktır.

ÖNEMLİ: Aşağıdaki Sieve süzgeçlerini uygulayarak, meşru iletilerin de süzgeçten geçirilmesine neden olabilecek bir hatalı pozitif riskiyle karşı karşıya kalabilirsiniz. Bu nedenle, süzgeci yalnızca saldırı süresince etkin tutmanızı öneririz.

Sieve süzgeci ile e-posta bombardımanı etkileri nasıl azaltılır

Proton Mail’in web sürümündeki hesabınızda mail.proton.me adresinden oturum açın ve aşağıdaki adımları takip edin:

1. E-posta bombardımanı saldırısının bir parçası olarak tanımlanan tüm e-postalara uygulanacak bir etiket oluşturun.

• Ayarlar -> Klasörler/Etiketler bölümüne gidin.
• “ETİKET EKLE” seçeneğine tıklayın, “Mail bomb” adında bir etiket oluşturun ve “Kaydet” seçeneğine tıklayın.

2. Tüm iletileri yok sayacak veya tüm iletileri İstenmeyen klasörünüze gönderecek bir Sieve süzgeci oluşturun.

• Ayarlar -> Süzgeçler bölümüne gidin ve “SIEVE SÜZGECİ EKLE” seçeneğine tıklayın.
• “Ad” alanında, Sieve süzgeciniz için bir ad oluşturun.
• “Sieve betiği” alanına, aşağıdaki kod seçeneklerinden birini kopyalayıp yapıştırın.

Aldığınız e-postaların özelliklerine ve süzgece yakalanan e-postalarla ne yapmak istediğinize bağlı olarak kullanabileceğiniz dört Sieve süzgeci seçeneği bulunmaktadır:

1. Belirli ortak anahtar kelimeleri içeren üst bilgi içeriğine dayanarak iletileri yok sayan bir süzgeç. Bu süzgeç uygulandığında, süzülen iletiler Gelen kutusuna asla ulaşmayacaktır; bu nedenle Sieve süzgeçlerini yalnızca saldırı süresince uygulamanızı öneririz:

if anyof (
    header "x-auto-response-suppress" ["OOF", "AutoReply"],
    header "precedence" "bulk",
    header "auto-submitted" "auto-generated",
    exists "form-sub",
    exists "list-unsubscribe",
    exists "x-php-script",
    exists "x-php-originating-script"
) {
    discard;
}

2. İlk seçeneğin biraz daha hafif bir varyasyonu. Bu süzgeç, iletileri yok saymak yerine İstenmeyen klasörünüze taşır ve “Mail bomb” etiketini uygular:

require "fileinto";
if anyof (
    header "x-auto-response-suppress" ["OOF", "AutoReply"],
    header "precedence" "bulk",
    header "auto-submitted" "auto-generated",
    exists "form-sub",
    exists "list-unsubscribe",
    exists "x-php-script",
    exists "x-php-originating-script"
) {
    fileinto "spam";
    fileinto "Mail bomb";
}

3. Gelen kayıt ve/veya abonelik formlarını İstenmeyen bölümüne taşıyan ve “Mail bomb” etiketini uygulayan bir süzgeç:

require "fileinto";
if allof (
    header :contains "Subject"
        [
            "subscription",
            "mailing",
            "subscribing",
            "confirm",
            "Welcome to",
            "activation",
            "verify",
            "registration",
            "activate",
            "your account",
            "verification",
            "signing up",
            "registering",
            "new account",
            "username and password",
            "registered",
            "welcome",
            "password",
            "account details",
            "verify your"
        ]
) {
    fileinto "spam";
    fileinto "Mail bomb";
}

4. Tüm duyuru iletilerini İstenmeyen klasörünüze taşıyan ve “Mail bomb” etiketini uygulayan bir süzgeç. Bu süzgeç aynı zamanda “mypapertoday.com” etki alanından gelen e-postalarla da eşleşecektir.

require "fileinto";
if anyof (
    header :contains "Subject" 
        [
            "Newsletteranmeldung",
            "Newsletterregistrierung",
            "Newsletter",
            "Anmeldung",
            "potwierdzenie",
            "subskrypcji",
            "inscripcin",
            "revista",
            "conferma",
            "inscrizione",
            "validation",
            "willkommen",
            "inscription",
            "account details",
            "Aktivierung",
            "Benutzerkontendetails",
            "bienvenue sur",
            "bienvenido",
            "новом пользователе",
            "benvenuto nel Forum",
            "Hoşgeldiniz",
            "Vítejte na",
            "пожаловать",
            "Bine aţi venit",
            "Üdvözlünk a",
            "fórumon",
            "Witamy na",
            "Velkommen til",
            "Tervetuloa",
            "unirte",
            "Welkom op",
            "activer",
            "Usuario",
            "Välkommen till",
            "Bem vindo",
            "Registrierungsanfrage",
            "注册",
            "подтверждения",
            "регистрацию",
            "Регистрационные",
            "konto",
            "dettagli account",
            "registratie",
            "conta",
            "cuenta",
            "compte",
            "registrazione",
            "contului",
            "konta",
            "aktivoi"
        ],
    address :domain :contains "From" "mypapertoday.com"
) {
    fileinto "Mail bomb";
    fileinto "spam";
}

İstenmeyen bölümüne taşınan iletiler için, iletilerin süzgece yanlışlıkla takılmadığından emin olmak amacıyla bunları daha sonra (“Mail bomb” etiketini arayarak) kolayca inceleyebilirsiniz. Bu süzgeç için kullanılan etiket, yukarıdaki 2 ila 4. adımlarda yer alan “Mail Bomb” ifadesi tercih ettiğiniz başka bir ifadeyle değiştirilerek kolayca özelleştirilebilir.

Lütfen ücretsiz tarifelerde kullanılabilecek süzgeç ve etiket sayısında sınırlamalar bulunduğunu unutmayın.

Son olarak, gelecekte benzer türde saldırıları nasıl önleyeceğiniz hakkında ayrıntılı bilgi almak için istenmeyen e-postaları engelleme konulu makalemizi okuyabilirsiniz.