Giảm thiểu bom email

Dội bom email là một hình thức tấn công trực tuyến, trong đó kẻ tấn công gửi một lượng lớn email đến một địa chỉ hoặc mạng máy tính cụ thể nhằm làm tràn hộp thư đến của người nhận.

Một hình thức ngày càng phổ biến của loại tấn công này là gửi dồn dập các email xác nhận đăng ký vào hộp thư người dùng.

Proton Mail cung cấp bộ lọc thư rác để ngăn các thư rác gửi đến hộp thư đến. Tuy nhiên, trong trường hợp bị tấn công bằng bom email, hoạt động gửi thư rác thường xuất phát từ các biểu mẫu đăng ký hợp lệ, điều này trong một số trường hợp có thể khiến bộ lọc thư rác không hiệu quả. Đối với những tình huống này, có thể sử dụng bộ lọc sieve nâng cao hơn. Bài viết này sẽ hướng dẫn các bước thêm bộ lọc sieve vào hộp thư đến.

QUAN TRỌNG: Bằng cách áp dụng các bộ lọc sieve bên dưới, có nguy cơ xảy ra nhận diện sai khiến các thư hợp lệ cũng bị lọc ra. Vì lý do này, khuyến nghị chỉ duy trì kích hoạt bộ lọc này trong thời gian diễn ra cuộc tấn công.

Cách giảm thiểu tác động của bom email bằng bộ lọc sieve

Đăng nhập vào tài khoản trên phiên bản web của Proton Mail tại mail.proton.me và thực hiện các bước sau:

1. Tạo một nhãn sẽ được áp dụng cho tất cả các email được xác định là một phần của cuộc tấn công bom thư.

• Đi tới Cài đặt -> Thư mục/Nhãn.
• Nhấp vào “THÊM NHÃN”, tạo một nhãn có tên là “Mail bomb” và nhấp vào “Lưu”.

2. Tạo một bộ lọc sieve để hủy bỏ tất cả các thư hoặc gửi tất cả các thư vào thư mục Thư rác.

• Đi tới Cài đặt -> Bộ lọc và nhấp vào “THÊM BỘ LỌC SIEVE”.
• Trong trường “Tên”, tạo tên cho bộ lọc sieve.
• Trong trường “Tập lệnh Sieve”, sao chép và dán một trong các tùy chọn mã bên dưới.

Có bốn tùy chọn bộ lọc sieve có thể sử dụng, tùy thuộc vào đặc điểm của các email nhận được và hành động muốn thực hiện đối với các email bị bộ lọc giữ lại:

1. Bộ lọc hủy bỏ các thư dựa trên nội dung tiêu đề có chứa một số từ khóa phổ biến. Khi bộ lọc này được áp dụng, các thư bị lọc sẽ không bao giờ đến được Hộp thư đến, đó là lý do tại sao khuyến nghị chỉ áp dụng các bộ lọc sieve trong thời gian diễn ra cuộc tấn công:

if anyof (
    header "x-auto-response-suppress" ["OOF", "AutoReply"],
    header "precedence" "bulk",
    header "auto-submitted" "auto-generated",
    exists "form-sub",
    exists "list-unsubscribe",
    exists "x-php-script",
    exists "x-php-originating-script"
) {
    discard;
}

2. Một biến thể nhẹ nhàng hơn một chút của tùy chọn đầu tiên. Thay vì hủy bỏ các thư, bộ lọc này sẽ di chuyển chúng vào thư mục Thư rác và áp dụng nhãn “Mail bomb”:

require "fileinto";
if anyof (
    header "x-auto-response-suppress" ["OOF", "AutoReply"],
    header "precedence" "bulk",
    header "auto-submitted" "auto-generated",
    exists "form-sub",
    exists "list-unsubscribe",
    exists "x-php-script",
    exists "x-php-originating-script"
) {
    fileinto "spam";
    fileinto "Mail bomb";
}

3. Bộ lọc di chuyển các biểu mẫu đăng ký và/hoặc đăng ký nhận tin gửi đến vào Thư rác và áp dụng nhãn “Mail bomb”:

require "fileinto";
if allof (
    header :contains "Subject"
        [
            "subscription",
            "mailing",
            "subscribing",
            "confirm",
            "Welcome to",
            "activation",
            "verify",
            "registration",
            "activate",
            "your account",
            "verification",
            "signing up",
            "registering",
            "new account",
            "username and password",
            "registered",
            "welcome",
            "password",
            "account details",
            "verify your"
        ]
) {
    fileinto "spam";
    fileinto "Mail bomb";
}

4. Bộ lọc di chuyển tất cả các thư bản tin vào thư mục Thư rác và áp dụng nhãn “Mail bomb”. Bộ lọc này cũng sẽ khớp với các email từ tên miền “mypapertoday.com”.

require "fileinto";
if anyof (
    header :contains "Subject" 
        [
            "Newsletteranmeldung",
            "Newsletterregistrierung",
            "Newsletter",
            "Anmeldung",
            "potwierdzenie",
            "subskrypcji",
            "inscripcin",
            "revista",
            "conferma",
            "inscrizione",
            "validation",
            "willkommen",
            "inscription",
            "account details",
            "Aktivierung",
            "Benutzerkontendetails",
            "bienvenue sur",
            "bienvenido",
            "новом пользователе",
            "benvenuto nel Forum",
            "Hoşgeldiniz",
            "Vítejte na",
            "пожаловать",
            "Bine aţi venit",
            "Üdvözlünk a",
            "fórumon",
            "Witamy na",
            "Velkommen til",
            "Tervetuloa",
            "unirte",
            "Welkom op",
            "activer",
            "Usuario",
            "Välkommen till",
            "Bem vindo",
            "Registrierungsanfrage",
            "注册",
            "подтверждения",
            "регистрацию",
            "Регистрационные",
            "konto",
            "dettagli account",
            "registratie",
            "conta",
            "cuenta",
            "compte",
            "registrazione",
            "contului",
            "konta",
            "aktivoi"
        ],
    address :domain :contains "From" "mypapertoday.com"
) {
    fileinto "Mail bomb";
    fileinto "spam";
}

Đối với các thư được di chuyển vào Thư rác, có thể dễ dàng xem lại sau (bằng cách tìm kiếm nhãn “Mail bomb”) để đảm bảo các thư không bị lọc nhầm. Nhãn được sử dụng cho bộ lọc này có thể dễ dàng thay đổi bằng cách thay thế cụm từ “Mail Bomb” trong các bước từ 2 đến 4 ở trên bằng bất kỳ tên nào mong muốn.

Lưu ý rằng các gói miễn phí có giới hạn về số lượng bộ lọc và nhãn có thể sử dụng.

Cuối cùng, có thể đọc bài viết về tránh thư rác để tìm hiểu thêm về cách ngăn ngừa các loại tấn công tương tự trong tương lai.