E-mailbommen tegengaan

Een e-mailbom is een soort online aanval waarbij de aanvaller een enorme hoeveelheid e-mails naar een specifiek adres of computernetwerk verzendt om de inbox van de ontvanger te overspoelen.

Een steeds vaker voorkomende vorm van deze aanval bestaat uit het bestoken van het postvak IN van de gebruiker met bevestigingsmails voor aanmelding.

Proton Mail biedt spamfiltering om te voorkomen dat spamberichten uw inbox bereiken. In het geval van e-mailbommen is de spamactiviteit echter meestal afkomstig van legitieme aanmeldingsformulieren, waardoor het spamfilter in sommige gevallen ondoeltreffend kan zijn. Voor deze situaties kunt u een geavanceerder Sieve-filter gebruiken. Dit artikel legt de stappen uit om een Sieve-filter aan uw Postvak in toe te voegen.

BELANGRIJK: Door de onderstaande Sieve-filters toe te passen, bestaat er een risico op valse positieven waardoor ook legitieme berichten worden uitgefilterd. Om deze reden raden we u aan deze alleen actief te houden voor de duur van de aanval.

Hoe u een e-mailbom kunt beperken met een Sieve-filter

Meld u aan bij uw account op de webversie van Proton Mail op mail.proton.me en volg deze stappen:

1. Maak een label aan dat wordt toegepast op alle e-mails die zijn geïdentificeerd als onderdeel van de e-mailbomaanval.

• Ga naar Instellingen -> Mappen/Labels.
• Klik op “LABEL TOEVOEGEN”, maak een label met de naam “Mail bomb” aan en klik op “Opslaan”.

2. Maak een Sieve-filter aan dat alle berichten weggooit of alle berichten naar uw Spam-map verzendt.

• Ga naar Instellingen -> Filters en klik op “SIEVE-FILTER TOEVOEGEN”.
• Maak in het veld “Naam” een naam aan voor uw Sieve-filter.
• Kopieer en plak een van de onderstaande code-opties in het veld “Sieve-script”.

Er zijn vier Sieve-filteropties die u kunt gebruiken, afhankelijk van de kenmerken van de e-mails die u ontvangt en wat u wilt doen met de e-mails die door het filter worden opgevangen:

1. Een filter dat de berichten weggooit op basis van de inhoud van de header die bepaalde veelvoorkomende trefwoorden bevat. Wanneer dit filter wordt toegepast, zullen de gefilterde berichten nooit het Postvak in bereiken. Daarom raden we aan om Sieve-filters alleen toe te passen voor de duur van de aanval:

if anyof (
    header "x-auto-response-suppress" ["OOF", "AutoReply"],
    header "precedence" "bulk",
    header "auto-submitted" "auto-generated",
    exists "form-sub",
    exists "list-unsubscribe",
    exists "x-php-script",
    exists "x-php-originating-script"
) {
    discard;
}

2. Een iets mildere variant van de eerste optie. In plaats van de berichten weg te gooien, verplaatst dit filter ze naar uw Spam-map en past het het label “Mail bomb” toe:

require "fileinto";
if anyof (
    header "x-auto-response-suppress" ["OOF", "AutoReply"],
    header "precedence" "bulk",
    header "auto-submitted" "auto-generated",
    exists "form-sub",
    exists "list-unsubscribe",
    exists "x-php-script",
    exists "x-php-originating-script"
) {
    fileinto "spam";
    fileinto "Mail bomb";
}

3. Een filter dat binnenkomende registratie- en/of abonnementsformulieren naar Spam verplaatst en het label “Mail bomb” toepast:

require "fileinto";
if allof (
    header :contains "Subject"
        [
            "subscription",
            "mailing",
            "subscribing",
            "confirm",
            "Welcome to",
            "activation",
            "verify",
            "registration",
            "activate",
            "your account",
            "verification",
            "signing up",
            "registering",
            "new account",
            "username and password",
            "registered",
            "welcome",
            "password",
            "account details",
            "verify your"
        ]
) {
    fileinto "spam";
    fileinto "Mail bomb";
}

4. Een filter dat alle nieuwsbriefberichten naar uw Spam-map verplaatst en het label “Mail bomb” toepast. Dit filter komt ook overeen met e-mails van het domein “mypapertoday.com”.

require "fileinto";
if anyof (
    header :contains "Subject" 
        [
            "Newsletteranmeldung",
            "Newsletterregistrierung",
            "Newsletter",
            "Anmeldung",
            "potwierdzenie",
            "subskrypcji",
            "inscripcin",
            "revista",
            "conferma",
            "inscrizione",
            "validation",
            "willkommen",
            "inscription",
            "account details",
            "Aktivierung",
            "Benutzerkontendetails",
            "bienvenue sur",
            "bienvenido",
            "новом пользователе",
            "benvenuto nel Forum",
            "Hoşgeldiniz",
            "Vítejte na",
            "пожаловать",
            "Bine aţi venit",
            "Üdvözlünk a",
            "fórumon",
            "Witamy na",
            "Velkommen til",
            "Tervetuloa",
            "unirte",
            "Welkom op",
            "activer",
            "Usuario",
            "Välkommen till",
            "Bem vindo",
            "Registrierungsanfrage",
            "注册",
            "подтверждения",
            "регистрацию",
            "Регистрационные",
            "konto",
            "dettagli account",
            "registratie",
            "conta",
            "cuenta",
            "compte",
            "registrazione",
            "contului",
            "konta",
            "aktivoi"
        ],
    address :domain :contains "From" "mypapertoday.com"
) {
    fileinto "Mail bomb";
    fileinto "spam";
}

Voor berichten die naar Spam zijn verplaatst, kunt u deze later eenvoudig controleren (door te zoeken naar het label “Mail bomb”) om er zeker van te zijn dat er geen berichten per ongeluk door het filter zijn tegengehouden. Het label dat voor dit filter wordt gebruikt, kan eenvoudig worden gewijzigd door simpelweg het woord “Mail Bomb” in de bovenstaande stappen 2 tot en met 4 te vervangen door wat uw voorkeur heeft.

Houd er rekening mee dat gratis abonnementen beperkingen hebben op het aantal filters en labels dat kan worden gebruikt.

Ten slotte kunt u ons artikel over het vermijden van spam lezen voor meer informatie over hoe u soortgelijke aanvallen in de toekomst kunt voorkomen.