Abwehr von E-Mail-Bomben

Eine E-Mail-Bombe ist eine Art Online-Angriff, bei dem der Angreifer eine riesige Menge an E-Mails an eine bestimmte Adresse oder ein Computernetzwerk sendet, um den Posteingang des Empfängers zu überfluten.

Eine immer häufigere Form dieses Angriffs besteht darin, das Postfach des Benutzers mit Bestätigungs-E-Mails für Registrierungen zu bombardieren.

Proton Mail bietet eine Spam-Filterung an, um zu verhindern, dass Spam-Nachrichten den Posteingang erreichen. Bei E-Mail-Bomben geht die Spam-Aktivität jedoch meist von legitimen Registrierungsformularen aus, was den Spamfilter in einigen Fällen unwirksam machen kann. Für diese Situationen kannst du einen fortgeschritteneren Sieve-Filter verwenden. In diesem Artikel werden die Schritte zum Hinzufügen eines Sieve-Filters zu deinem Posteingang erklärt.

WICHTIG: Durch das Anwenden der folgenden Sieve-Filter besteht das Risiko von Fehlalarmen (False Positives), wodurch auch legitime Nachrichten herausgefiltert werden. Aus diesem Grund empfehlen wir, ihn nur für die Dauer des Angriffs aktiv zu lassen.

So dämmst du eine E-Mail-Bombe mit einem Sieve-Filter ein

Melde dich in der Web-Version von Proton Mail unter mail.proton.me in deinem Konto an und folge diesen Schritten:

1. Erstelle eine Kategorie, die auf alle E-Mails angewendet wird, die als Teil des Mail-Bomben-Angriffs identifiziert wurden.

• Gehe zu Einstellungen -> Ordner/Kategorien.
• Klicke auf „Kategorie hinzuf.“, erstelle eine Kategorie namens „Mail bomb“ und klicke auf „Speichern“.

2. Erstelle einen Sieve-Filter, der entweder alle Nachrichten verwirft oder alle Nachrichten in deinen Spam-Ordner sendet.

• Gehe zu Einstellungen -> Filter und klicke auf „SIEVE-FILTER HINZUFÜGEN“.
• Erstelle im Feld „Name“ einen Namen für deinen Sieve-Filter.
• Kopiere eine der folgenden Code-Optionen und füge sie in das Feld „Sieve-Skript“ ein.

Es gibt vier Optionen für Sieve-Filter, die du verwenden kannst, je nach den Merkmalen der E-Mails, die du erhältst, und dem, was du mit den vom Filter erfassten E-Mails tun möchtest:

1. Ein Filter, der die Nachrichten basierend auf dem Inhalt der Kopfzeile verwirft, der bestimmte gängige Schlüsselwörter enthält. Wenn dieser Filter angewendet wird, erreichen die gefilterten Nachrichten niemals den Posteingang. Aus diesem Grund empfehlen wir, Sieve-Filter nur für die Dauer des Angriffs anzuwenden:

if anyof (
    header "x-auto-response-suppress" ["OOF", "AutoReply"],
    header "precedence" "bulk",
    header "auto-submitted" "auto-generated",
    exists "form-sub",
    exists "list-unsubscribe",
    exists "x-php-script",
    exists "x-php-originating-script"
) {
    discard;
}

2. Eine etwas mildere Variante der ersten Option. Anstatt die Nachrichten zu verwerfen, verschiebt dieser Filter sie in deinen Spam-Ordner und wendet die Kategorie „Mail bomb“ an:

require "fileinto";
if anyof (
    header "x-auto-response-suppress" ["OOF", "AutoReply"],
    header "precedence" "bulk",
    header "auto-submitted" "auto-generated",
    exists "form-sub",
    exists "list-unsubscribe",
    exists "x-php-script",
    exists "x-php-originating-script"
) {
    fileinto "spam";
    fileinto "Mail bomb";
}

3. Ein Filter, der eingehende Registrierungs- und/oder Abonnementformulare in den Spam-Ordner verschiebt und die Kategorie „Mail bomb“ anwendet:

require "fileinto";
if allof (
    header :contains "Subject"
        [
            "subscription",
            "mailing",
            "subscribing",
            "confirm",
            "Welcome to",
            "activation",
            "verify",
            "registration",
            "activate",
            "your account",
            "verification",
            "signing up",
            "registering",
            "new account",
            "username and password",
            "registered",
            "welcome",
            "password",
            "account details",
            "verify your"
        ]
) {
    fileinto "spam";
    fileinto "Mail bomb";
}

4. Ein Filter, der alle Newsletter-Nachrichten in deinen Spam-Ordner verschiebt und die Kategorie „Mail bomb“ anwendet. Dieser Filter erfasst auch E-Mails von der Domain „mypapertoday.com“.

require "fileinto";
if anyof (
    header :contains "Subject" 
        [
            "Newsletteranmeldung",
            "Newsletterregistrierung",
            "Newsletter",
            "Anmeldung",
            "potwierdzenie",
            "subskrypcji",
            "inscripcin",
            "revista",
            "conferma",
            "inscrizione",
            "validation",
            "willkommen",
            "inscription",
            "account details",
            "Aktivierung",
            "Benutzerkontendetails",
            "bienvenue sur",
            "bienvenido",
            "новом пользователе",
            "benvenuto nel Forum",
            "Hoşgeldiniz",
            "Vítejte na",
            "пожаловать",
            "Bine aţi venit",
            "Üdvözlünk a",
            "fórumon",
            "Witamy na",
            "Velkommen til",
            "Tervetuloa",
            "unirte",
            "Welkom op",
            "activer",
            "Usuario",
            "Välkommen till",
            "Bem vindo",
            "Registrierungsanfrage",
            "注册",
            "подтверждения",
            "регистрацию",
            "Регистрационные",
            "konto",
            "dettagli account",
            "registratie",
            "conta",
            "cuenta",
            "compte",
            "registrazione",
            "contului",
            "konta",
            "aktivoi"
        ],
    address :domain :contains "From" "mypapertoday.com"
) {
    fileinto "Mail bomb";
    fileinto "spam";
}

Nachrichten, die in den Spam-Ordner verschoben wurden, kannst du später ganz einfach überprüfen (indem du nach der Kategorie „Mail bomb“ suchst), um sicherzustellen, dass keine Nachrichten fälschlicherweise vom Filter erfasst wurden. Die für diesen Filter verwendete Kategorie lässt sich leicht ändern, indem du einfach das Wort „Mail Bomb“ in den obigen Schritten 2 bis 4 durch einen Namen deiner Wahl ersetzt.

Bitte beachte, dass kostenlose Abonnements Einschränkungen bei der Anzahl der Filter und Kategorien haben, die verwendet werden können.

Schließlich kannst du unseren Artikel über das Vermeiden von Spam lesen, um mehr darüber zu erfahren, wie du ähnliche Angriffe in Zukunft verhindern kannst.