Mitigering af e-mailbomber

En e-mailbombe er en form for onlineangreb, hvor angriberen sender en enorm mængde e-mails til en specifik adresse eller et computernetværk med det formål at oversvømme modtagerens indbakke.

En stadig mere almindelig form for dette angreb består i at bombardere brugerens postkasse med bekræftelsesmails til tilmelding.

Proton Mail tilbyder spamfiltrering for at forhindre spambeskeder i at nå indbakken. Men i tilfælde af e-mailbomber har spamaktiviteten tendens til at komme fra legitime tilmeldingsformularer, hvilket i nogle tilfælde kan gøre spamfiltret ineffektivt. I disse situationer kan De anvende et mere avanceret Sieve-filter. Denne artikel vil forklare trinene til at tilføje et Sieve-filter til Deres indbakke.

VIGTIGT: Ved at anvende nedenstående Sieve-filtre er der risiko for falske positive resultater, som også vil frasortere legitime beskeder. Af denne årsag anbefaler vi kun at holde det aktivt, så længe angrebet varer.

Sådan afbødes en e-mailbombe med et Sieve-filter

Log ind på Deres konto på webversionen af Proton Mail på mail.proton.me, og følg disse trin:

1. Opret en etiket, som vil blive anvendt på alle e-mails, der identificeres som en del af e-mailbombeangrebet.

• Gå til Indstillinger -> Mapper/Etiketter.
• Klik på “TILFØJ ETIKET”, opret en etiket med navnet “Mailbombe” og klik på “Gem”.

2. Opret et Sieve-filter, som enten vil kassere alle beskeder eller sende alle beskeder til Deres spam-mappe.

• Gå til Indstillinger -> Filtre og klik på “TILFØJ SIEVE-FILTER”.
• I feltet “Navn” skal De oprette et navn til Deres Sieve-filter.
• I feltet “Sieve-script” skal De kopiere og indsætte en af nedenstående kodemuligheder.

Der er fire Sieve-filtermuligheder, De kan bruge, afhængigt af egenskaberne ved de e-mails, De modtager, og hvad De ønsker at gøre med de e-mails, der fanges af filtret:

1. Et filter, der kasserer beskederne baseret på indholdet af overskriften, som indeholder visse almindelige nøgleord. Når dette filter anvendes, vil de filtrerede beskeder aldrig nå indbakken, hvilket er grunden til, at vi foreslår kun at anvende Sieve-filtre, så længe angrebet varer:

if anyof (
    header "x-auto-response-suppress" ["OOF", "AutoReply"],
    header "precedence" "bulk",
    header "auto-submitted" "auto-generated",
    exists "form-sub",
    exists "list-unsubscribe",
    exists "x-php-script",
    exists "x-php-originating-script"
) {
    discard;
}

2. En lidt blidere variant af den første mulighed. I stedet for at kassere beskederne flytter dette filter dem til Deres spam-mappe og anvender etiketten “Mailbombe”:

require "fileinto";
if anyof (
    header "x-auto-response-suppress" ["OOF", "AutoReply"],
    header "precedence" "bulk",
    header "auto-submitted" "auto-generated",
    exists "form-sub",
    exists "list-unsubscribe",
    exists "x-php-script",
    exists "x-php-originating-script"
) {
    fileinto "spam";
    fileinto "Mail bomb";
}

3. Et filter, der flytter indgående registrerings- og/eller abonnementsformularer til spam og anvender etiketten “Mailbombe”:

require "fileinto";
if allof (
    header :contains "Subject"
        [
            "subscription",
            "mailing",
            "subscribing",
            "confirm",
            "Welcome to",
            "activation",
            "verify",
            "registration",
            "activate",
            "your account",
            "verification",
            "signing up",
            "registering",
            "new account",
            "username and password",
            "registered",
            "welcome",
            "password",
            "account details",
            "verify your"
        ]
) {
    fileinto "spam";
    fileinto "Mail bomb";
}

4. Et filter, der flytter alle nyhedsbrevsbeskeder til Deres spam-mappe og anvender etiketten “Mailbombe”. Dette filter vil også matche e-mails fra domænet “mypapertoday.com”.

require "fileinto";
if anyof (
    header :contains "Subject" 
        [
            "Newsletteranmeldung",
            "Newsletterregistrierung",
            "Newsletter",
            "Anmeldung",
            "potwierdzenie",
            "subskrypcji",
            "inscripcin",
            "revista",
            "conferma",
            "inscrizione",
            "validation",
            "willkommen",
            "inscription",
            "account details",
            "Aktivierung",
            "Benutzerkontendetails",
            "bienvenue sur",
            "bienvenido",
            "новом пользователе",
            "benvenuto nel Forum",
            "Hoşgeldiniz",
            "Vítejte na",
            "пожаловать",
            "Bine aţi venit",
            "Üdvözlünk a",
            "fórumon",
            "Witamy na",
            "Velkommen til",
            "Tervetuloa",
            "unirte",
            "Welkom op",
            "activer",
            "Usuario",
            "Välkommen till",
            "Bem vindo",
            "Registrierungsanfrage",
            "注册",
            "подтверждения",
            "регистрацию",
            "Регистрационные",
            "konto",
            "dettagli account",
            "registratie",
            "conta",
            "cuenta",
            "compte",
            "registrazione",
            "contului",
            "konta",
            "aktivoi"
        ],
    address :domain :contains "From" "mypapertoday.com"
) {
    fileinto "Mail bomb";
    fileinto "spam";
}

For beskeder, der flyttes til spam, kan De nemt gennemse dem senere (ved at søge efter etiketten “Mailbombe”) for at sikre, at beskederne ikke blev fanget i filtret ved en fejl. Den etiket, der bruges til dette filter, kan nemt ændres ved blot at erstatte ordet “Mailbombe” i trin 2 til 4 ovenfor med det, De foretrækker.

Bemærk venligst, at gratis abonnementer har begrænsninger på antallet af filtre og etiketter, der kan anvendes.

Endelig kan De læse vores artikel om at undgå spam for at få mere at vide om, hvordan De forhindrer lignende typer angreb i fremtiden.