Obrana proti e-mailovému bombardování

E-mailová bomba je druh online útoku, při kterém útočník odesílá obrovské množství e-mailů na konkrétní adresu nebo do počítačové sítě s cílem přeplnit doručenou poštu příjemce.

Stále častější forma tohoto útoku spočívá v zahlcování e-mailové schránky uživatele potvrzovacími e-maily o registraci.

Proton Mail nabízí filtrování spamu, aby zabránil doručení spamových zpráv do doručené pošty. V případě e-mailových bomb však spamová aktivita často pochází z legitimních registračních formulářů, což může v některých případech způsobit, že je filtr spamu neúčinný. V těchto situacích můžete použít pokročilejší filtr Sieve. Tento článek vám vysvětlí kroky, jak přidat filtr Sieve do vaší doručené pošty.

DŮLEŽITÉ: Použitím níže uvedených filtrů Sieve hrozí riziko falešně pozitivních výsledků, které odfiltrují i legitimní zprávy. Z tohoto důvodu doporučujeme ponechat je aktivní pouze po dobu útoku.

Jak zmírnit e-mailovou bombu pomocí filtru Sieve

Přihlaste se ke svému účtu ve webové verzi Proton Mail na adrese mail.proton.me a postupujte podle následujících kroků:

1. Vytvořte štítek, který se použije na všechny e-maily identifikované jako součást útoku e-mailovou bombou.

• Přejděte do Nastavení -> Složky/Štítky.
• Klikněte na „PŘIDAT ŠTÍTEK“, vytvořte štítek s názvem „Mail bomb“ a klikněte na „Uložit“.

2. Vytvořte filtr Sieve, který buď zahodí všechny zprávy, nebo je všechny odešle do vaší složky Spam.

• Přejděte do Nastavení -> Filtry a klikněte na „PŘIDAT FILTR SIEVE“.
• Do pole „Název“ vytvořte název pro svůj filtr Sieve.
• Do pole „Sieve skript“ zkopírujte a vložte jednu z níže uvedených možností kódu.

K dispozici jsou čtyři možnosti filtrů Sieve, které můžete použít v závislosti na vlastnostech přijímaných e-mailů a na tom, co chcete s e-maily zachycenými filtrem udělat:

1. Filtr, který zahazuje zprávy na základě obsahu hlavičky obsahujícího určitá běžná klíčová slova. Při použití tohoto filtru se filtrované zprávy nikdy nedostanou do doručené pošty, což je důvod, proč doporučujeme používat filtry Sieve pouze po dobu útoku:

if anyof (
    header "x-auto-response-suppress" ["OOF", "AutoReply"],
    header "precedence" "bulk",
    header "auto-submitted" "auto-generated",
    exists "form-sub",
    exists "list-unsubscribe",
    exists "x-php-script",
    exists "x-php-originating-script"
) {
    discard;
}

2. O něco mírnější varianta první možnosti. Místo zahazování zpráv je tento filtr přesune do vaší složky Spam a použije štítek „Mail bomb“:

require "fileinto";
if anyof (
    header "x-auto-response-suppress" ["OOF", "AutoReply"],
    header "precedence" "bulk",
    header "auto-submitted" "auto-generated",
    exists "form-sub",
    exists "list-unsubscribe",
    exists "x-php-script",
    exists "x-php-originating-script"
) {
    fileinto "spam";
    fileinto "Mail bomb";
}

3. Filtr, který přesouvá příchozí registrační a/nebo přihlašovací formuláře k odběru do složky Spam a použije štítek „Mail bomb“:

require "fileinto";
if allof (
    header :contains "Subject"
        [
            "subscription",
            "mailing",
            "subscribing",
            "confirm",
            "Welcome to",
            "activation",
            "verify",
            "registration",
            "activate",
            "your account",
            "verification",
            "signing up",
            "registering",
            "new account",
            "username and password",
            "registered",
            "welcome",
            "password",
            "account details",
            "verify your"
        ]
) {
    fileinto "spam";
    fileinto "Mail bomb";
}

4. Filtr, který přesouvá všechny e-mailové zpravodaje do vaší složky Spam a použije štítek „Mail bomb“. Tento filtr bude také zachycovat e-maily z domény „mypapertoday.com“.

require "fileinto";
if anyof (
    header :contains "Subject" 
        [
            "Newsletteranmeldung",
            "Newsletterregistrierung",
            "Newsletter",
            "Anmeldung",
            "potwierdzenie",
            "subskrypcji",
            "inscripcin",
            "revista",
            "conferma",
            "inscrizione",
            "validation",
            "willkommen",
            "inscription",
            "account details",
            "Aktivierung",
            "Benutzerkontendetails",
            "bienvenue sur",
            "bienvenido",
            "новом пользователе",
            "benvenuto nel Forum",
            "Hoşgeldiniz",
            "Vítejte na",
            "пожаловать",
            "Bine aţi venit",
            "Üdvözlünk a",
            "fórumon",
            "Witamy na",
            "Velkommen til",
            "Tervetuloa",
            "unirte",
            "Welkom op",
            "activer",
            "Usuario",
            "Välkommen till",
            "Bem vindo",
            "Registrierungsanfrage",
            "注册",
            "подтверждения",
            "регистрацию",
            "Регистрационные",
            "konto",
            "dettagli account",
            "registratie",
            "conta",
            "cuenta",
            "compte",
            "registrazione",
            "contului",
            "konta",
            "aktivoi"
        ],
    address :domain :contains "From" "mypapertoday.com"
) {
    fileinto "Mail bomb";
    fileinto "spam";
}

Zprávy přesunuté do složky Spam můžete později snadno zkontrolovat (vyhledáním štítku „Mail bomb“), abyste se ujistili, že nebyly filtrem zachyceny omylem. Štítek použitý pro tento filtr lze snadno změnit jednoduchým nahrazením slov „Mail bomb“ v krocích 2 až 4 výše čímkoli, čemu dáváte přednost.

Upozorňujeme, že bezplatné tarify mají omezení počtu filtrů a štítků, které lze použít.

Na závěr si můžete přečíst náš článek o předcházení spamu, kde se dozvíte více o tom, jak podobným typům útoků v budoucnu předcházet.