Atenuarea bombelor de e-mail

Un bombardament cu e-mailuri este un tip de atac online în care atacatorul trimite o cantitate masivă de e-mailuri către o adresă specifică sau o rețea de computere pentru a supraîncărca inbox-ul destinatarului.

O formă din ce în ce mai comună a acestui atac constă în bombardarea căsuței poștale a utilizatorului cu e-mailuri de confirmare a înscrierii.

Proton Mail oferă filtrare mesaje spam pentru a preveni ca mesajele spam să ajungă în inbox. Cu toate acestea, în cazul bombelor de e-mail, activitatea de trimitere a spamului tinde să provină de la formulare de înregistrare legitime, ceea ce poate face, în unele cazuri, ca filtrul de spam să fie ineficient. Pentru aceste situații, puteți utiliza un filtru Sieve mai avansat. Acest articol va explica pașii pentru a adăuga un filtru Sieve în inboxul dvs.

IMPORTANT: Prin aplicarea filtrelor Sieve de mai jos, există riscul de rezultate fals pozitive, care vor filtra și mesajele legitime. Din acest motiv, vă recomandăm să le mențineți active doar pe durata atacului.

Cum să atenuați o bombă de e-mail cu un filtru Sieve

Conectați-vă la contul dvs. pe versiunea web a Proton Mail la adresa mail.proton.me și urmați acești pași:

1. Creați o etichetă care va fi aplicată tuturor e-mailurilor identificate ca fiind parte a atacului de tip bombă de e-mail.

• Accesați Setări -> Foldere/Etichete.
• Faceți clic pe „ADĂUGARE ETICHETĂ”, creați o etichetă numită „Mail bomb” și faceți clic pe „Salvare”.

2. Creați un filtru Sieve care fie va elimina toate mesajele, fie va trimite toate mesajele în folderul dvs. Spam.

• Accesați Setări -> Filtre și faceți clic pe „ADĂUGARE FILTRU SIEVE”.
• În câmpul „Nume”, creați un nume pentru filtrul dvs. Sieve.
• În câmpul „Script Sieve”, copiați și lipiți una dintre opțiunile de cod de mai jos.

Există patru opțiuni de filtre Sieve pe care le puteți utiliza, în funcție de caracteristicile e-mailurilor pe care le primiți și de ceea ce doriți să faceți cu e-mailurile prinse de filtru:

1. Un filtru care elimină mesajele pe baza conținutului antetului care conține anumite cuvinte-cheie comune. Atunci când acest filtru este aplicat, mesajele filtrate nu vor ajunge niciodată în inbox, motiv pentru care vă sugerăm să aplicați filtrele Sieve doar pe durata atacului:

if anyof (
    header "x-auto-response-suppress" ["OOF", "AutoReply"],
    header "precedence" "bulk",
    header "auto-submitted" "auto-generated",
    exists "form-sub",
    exists "list-unsubscribe",
    exists "x-php-script",
    exists "x-php-originating-script"
) {
    discard;
}

2. O variantă ceva mai moderată a primei opțiuni. În loc să elimine mesajele, acest filtru le mută în folderul dvs. Spam și aplică eticheta „Mail bomb”:

require "fileinto";
if anyof (
    header "x-auto-response-suppress" ["OOF", "AutoReply"],
    header "precedence" "bulk",
    header "auto-submitted" "auto-generated",
    exists "form-sub",
    exists "list-unsubscribe",
    exists "x-php-script",
    exists "x-php-originating-script"
) {
    fileinto "spam";
    fileinto "Mail bomb";
}

3. Un filtru care mută formularele primite de înregistrare și/sau abonare în folderul Spam și aplică eticheta „Mail bomb”:

require "fileinto";
if allof (
    header :contains "Subject"
        [
            "subscription",
            "mailing",
            "subscribing",
            "confirm",
            "Welcome to",
            "activation",
            "verify",
            "registration",
            "activate",
            "your account",
            "verification",
            "signing up",
            "registering",
            "new account",
            "username and password",
            "registered",
            "welcome",
            "password",
            "account details",
            "verify your"
        ]
) {
    fileinto "spam";
    fileinto "Mail bomb";
}

4. Un filtru care mută toate mesajele de tip buletin informativ în folderul dvs. Spam și aplică eticheta „Mail bomb”. Acest filtru se va potrivi și cu e-mailurile de pe domeniul „mypapertoday.com”.

require "fileinto";
if anyof (
    header :contains "Subject" 
        [
            "Newsletteranmeldung",
            "Newsletterregistrierung",
            "Newsletter",
            "Anmeldung",
            "potwierdzenie",
            "subskrypcji",
            "inscripcin",
            "revista",
            "conferma",
            "inscrizione",
            "validation",
            "willkommen",
            "inscription",
            "account details",
            "Aktivierung",
            "Benutzerkontendetails",
            "bienvenue sur",
            "bienvenido",
            "новом пользователе",
            "benvenuto nel Forum",
            "Hoşgeldiniz",
            "Vítejte na",
            "пожаловать",
            "Bine aţi venit",
            "Üdvözlünk a",
            "fórumon",
            "Witamy na",
            "Velkommen til",
            "Tervetuloa",
            "unirte",
            "Welkom op",
            "activer",
            "Usuario",
            "Välkommen till",
            "Bem vindo",
            "Registrierungsanfrage",
            "注册",
            "подтверждения",
            "регистрацию",
            "Регистрационные",
            "konto",
            "dettagli account",
            "registratie",
            "conta",
            "cuenta",
            "compte",
            "registrazione",
            "contului",
            "konta",
            "aktivoi"
        ],
    address :domain :contains "From" "mypapertoday.com"
) {
    fileinto "Mail bomb";
    fileinto "spam";
}

Pentru mesajele mutate în folderul Spam, le puteți revizui cu ușurință mai târziu (căutând eticheta „Mail bomb”) pentru a vă asigura că mesajele nu au fost prinse de filtru din greșeală. Eticheta utilizată pentru acest filtru poate fi schimbată cu ușurință înlocuind pur și simplu expresia „Mail bomb” din pașii 2 până la 4 de mai sus cu orice doriți.

Vă rugăm să rețineți că planurile gratuite au limitări privind numărul de filtre și etichete care pot fi utilizate.

În cele din urmă, puteți citi articolul nostru despre evitarea spamului pentru a afla mai multe despre cum să preveniți atacuri similare în viitor.