Mottiltak mot e-postbombe

En e-postbombe er en form for nettangrep der angriperen sender en enorm mengde e-poster til en bestemt adresse eller et datamaskinnettverk for å oversvømme mottakerens innboks.

En stadig mer vanlig form for dette angrepet består i å bombardere brukerens innboks med e-postbekreftelser på registrering.

Proton Mail tilbyr filtrering av søppelpost for å forhindre at søppelpostmeldinger når innboksen. I tilfeller med e-postbomber har imidlertid søppelpostaktiviteten en tendens til å komme fra legitime registreringsskjemaer, noe som i enkelte tilfeller kan gjøre søppelpostfilteret ineffektivt. I slike situasjoner kan du bruke et mer avansert Sieve-filter. Denne artikkelen forklarer trinnene for å legge til et Sieve-filter i innboksen din.

VIKTIG: Ved å bruke Sieve-filtrene nedenfor er det en risiko for falske positiver som også vil filtrere ut legitime meldinger. Av denne grunn anbefaler vi at du bare holder det aktivt så lenge angrepet varer.

Slik begrenser du en e-postbombe med et Sieve-filter

Logg på kontoen din i nettversjonen av Proton Mail på mail.proton.me, og følg disse trinnene:

1. Opprett en etikett som vil bli brukt på alle e-poster som identifiseres som en del av e-postbombeangrepet.

• Gå til Innstillinger -> Mapper/Etiketter.
• Klikk på «LEGG TIL ETIKETT», opprett en etikett med navnet «Mail bomb» og klikk på «Lagre».

2. Opprett et Sieve-filter som enten vil forkaste alle meldinger eller sende alle meldinger til søppelpostmappen din.

• Gå til Innstillinger -> Filtre og klikk på «LEGG TIL SIEVE-FILTER».
• I «Navn»-feltet oppretter du et navn på Sieve-filteret ditt.
• I «Sieve-skript»-feltet kopierer og limer du inn et av kodealternativene nedenfor.

Det finnes fire Sieve-filteralternativer du kan bruke, avhengig av egenskapene til e-postene du mottar, og hva du vil gjøre med e-postene som fanges opp av filteret:

1. Et filter som forkaster meldingene basert på innholdet i toppteksten som inneholder visse vanlige nøkkelord. Når dette filteret tas i bruk, vil de filtrerte meldingene aldri nå innboksen, og det er grunnen til at vi foreslår å bare bruke Sieve-filtre så lenge angrepet varer:

if anyof (
    header "x-auto-response-suppress" ["OOF", "AutoReply"],
    header "precedence" "bulk",
    header "auto-submitted" "auto-generated",
    exists "form-sub",
    exists "list-unsubscribe",
    exists "x-php-script",
    exists "x-php-originating-script"
) {
    discard;
}

2. En litt mildere variant av det første alternativet. I stedet for å forkaste meldingene, flytter dette filteret dem til søppelpostmappen din og tar i bruk etiketten «Mail bomb»:

require "fileinto";
if anyof (
    header "x-auto-response-suppress" ["OOF", "AutoReply"],
    header "precedence" "bulk",
    header "auto-submitted" "auto-generated",
    exists "form-sub",
    exists "list-unsubscribe",
    exists "x-php-script",
    exists "x-php-originating-script"
) {
    fileinto "spam";
    fileinto "Mail bomb";
}

3. Et filter som flytter innkommende registrerings- og/eller abonnementsskjemaer til søppelpost og bruker etiketten «Mail bomb»:

require "fileinto";
if allof (
    header :contains "Subject"
        [
            "subscription",
            "mailing",
            "subscribing",
            "confirm",
            "Welcome to",
            "activation",
            "verify",
            "registration",
            "activate",
            "your account",
            "verification",
            "signing up",
            "registering",
            "new account",
            "username and password",
            "registered",
            "welcome",
            "password",
            "account details",
            "verify your"
        ]
) {
    fileinto "spam";
    fileinto "Mail bomb";
}

4. Et filter som flytter alle nyhetsbrevmeldinger til søppelpostmappen din og bruker etiketten «Mail bomb». Dette filteret vil også matche e-poster fra domenet «mypapertoday.com».

require "fileinto";
if anyof (
    header :contains "Subject" 
        [
            "Newsletteranmeldung",
            "Newsletterregistrierung",
            "Newsletter",
            "Anmeldung",
            "potwierdzenie",
            "subskrypcji",
            "inscripcin",
            "revista",
            "conferma",
            "inscrizione",
            "validation",
            "willkommen",
            "inscription",
            "account details",
            "Aktivierung",
            "Benutzerkontendetails",
            "bienvenue sur",
            "bienvenido",
            "новом пользователе",
            "benvenuto nel Forum",
            "Hoşgeldiniz",
            "Vítejte na",
            "пожаловать",
            "Bine aţi venit",
            "Üdvözlünk a",
            "fórumon",
            "Witamy na",
            "Velkommen til",
            "Tervetuloa",
            "unirte",
            "Welkom op",
            "activer",
            "Usuario",
            "Välkommen till",
            "Bem vindo",
            "Registrierungsanfrage",
            "注册",
            "подтверждения",
            "регистрацию",
            "Регистрационные",
            "konto",
            "dettagli account",
            "registratie",
            "conta",
            "cuenta",
            "compte",
            "registrazione",
            "contului",
            "konta",
            "aktivoi"
        ],
    address :domain :contains "From" "mypapertoday.com"
) {
    fileinto "Mail bomb";
    fileinto "spam";
}

For meldinger som er flyttet til søppelpost, kan du enkelt gå gjennom dem senere (ved å søke etter etiketten «Mail bomb») for å sikre at meldinger ikke ble fanget opp i filteret ved en feiltakelse. Etiketten som brukes for dette filteret, kan enkelt endres ved å bytte ut ordet «Mail Bomb» i trinn 2 til 4 ovenfor med det du foretrekker.

Vær oppmerksom på at gratisabonnementer har begrensninger på antall filtre og etiketter som kan brukes.

Til slutt kan du lese artikkelen vår om å unngå søppelpost for å finne ut mer om hvordan du kan forhindre lignende typer angrep i fremtiden.