การบรรเทาผลกระทบจากอีเมลบอมบ์

เวลาอ่าน: 1 นาที
หมวดหมู่: รับและอ่านอีเมล

ระเบิดอีเมลคือการโจมตีออนไลน์ประเภทหนึ่งที่ผู้โจมตีส่งอีเมลจำนวนมหาศาลไปยังที่อยู่หรือเครือข่ายคอมพิวเตอร์ที่เจาะจง เพื่อทำให้กล่องขาเข้าของผู้รับล้น

รูปแบบที่พบได้บ่อยขึ้นเรื่อยๆ ของการโจมตีนี้คือการส่งอีเมลยืนยันการสมัครใช้งานจำนวนมากไปยังกล่องจดหมายของผู้ใช้

Proton Mail มี ตัวกรองสแปมเพื่อป้องกันไม่ให้ข้อความสแปมเข้ามายังกล่องขาเข้า อย่างไรก็ตาม ในกรณีของการส่งอีเมลบอมบ์ กิจกรรมสแปมมักจะมาจากฟอร์มลงทะเบียนที่ถูกต้อง ซึ่งในบางกรณีอาจทำให้ตัวกรองสแปมไม่มีประสิทธิภาพ สำหรับสถานการณ์เหล่านี้ สามารถใช้ตัวกรอง Sieve ที่ขั้นสูงกว่าได้ บทความนี้จะอธิบายขั้นตอนการเพิ่มตัวกรอง Sieve ไปยังกล่องขาเข้า

สำคัญ: การนำตัวกรอง Sieve ด้านล่างนี้ไปใช้อาจมีความเสี่ยงที่จะเกิดการตรวจจับที่ผิดพลาด (false positives) ซึ่งจะกรองข้อความที่ถูกต้องออกไปด้วย ด้วยเหตุนี้ จึงขอแนะนำให้เปิดใช้งานเฉพาะในช่วงเวลาที่ถูกโจมตีเท่านั้น

วิธีบรรเทาผลกระทบจากการโจมตีด้วยอีเมลบอมบ์ด้วยตัวกรอง Sieve

เข้าสู่ระบบบัญชีบน Proton Mail เวอร์ชันเว็บที่ mail.proton.me และทำตามขั้นตอนต่อไปนี้:

1. สร้างป้ายกำกับที่จะนำไปใช้กับอีเมลทั้งหมดที่ระบุว่าเป็นส่วนหนึ่งของการโจมตีด้วยอีเมลบอมบ์

ไปที่ การตั้งค่า -> โฟลเดอร์/ป้ายกำกับ
คลิกที่ “เพิ่มป้ายกำกับ” สร้างป้ายกำกับชื่อ “Mail bomb” แล้วคลิก “บันทึก”

2. สร้างตัวกรอง Sieve ที่จะละทิ้งข้อความทั้งหมดหรือส่งข้อความทั้งหมดไปยังโฟลเดอร์สแปม

ไปที่ การตั้งค่า -> ตัวกรอง แล้วคลิกที่ “เพิ่มตัวกรอง SIEVE”
ในช่องข้อมูล “ชื่อ” ให้สร้างชื่อสำหรับตัวกรอง Sieve
ในช่องข้อมูล “สคริปต์ Sieve” ให้คัดลอกและวางตัวเลือกรหัสข้อใดข้อหนึ่งด้านล่างนี้

มีตัวเลือกตัวกรอง Sieve อยู่สี่ตัวเลือกที่สามารถใช้ได้ ทั้งนี้ขึ้นอยู่กับลักษณะของอีเมลที่ได้รับและสิ่งที่ต้องการดำเนินการกับอีเมลที่ถูกกรอง:

1. ตัวกรองที่ละทิ้งข้อความโดยอิงตามเนื้อหาส่วนหัวที่มีคีย์เวิร์ดทั่วไปบางคำ เมื่อนำตัวกรองนี้ไปใช้ ข้อความที่ถูกกรองจะไม่มาถึงกล่องขาเข้าเลย จึงเป็นสาเหตุที่แนะนำให้นำตัวกรอง Sieve ไปใช้เฉพาะในช่วงเวลาที่ถูกโจมตีเท่านั้น:

if anyof (
    header "x-auto-response-suppress" ["OOF", "AutoReply"],
    header "precedence" "bulk",
    header "auto-submitted" "auto-generated",
    exists "form-sub",
    exists "list-unsubscribe",
    exists "x-php-script",
    exists "x-php-originating-script"
) {
    discard;
}

คัดลอกแล้ว

2. ตัวเลือกแรกในเวอร์ชันที่เบากว่าเล็กน้อย แทนที่จะละทิ้งข้อความ ตัวกรองนี้จะย้ายข้อความไปยังโฟลเดอร์สแปมและนำป้ายกำกับ “Mail bomb” ไปใช้:

require "fileinto";
if anyof (
    header "x-auto-response-suppress" ["OOF", "AutoReply"],
    header "precedence" "bulk",
    header "auto-submitted" "auto-generated",
    exists "form-sub",
    exists "list-unsubscribe",
    exists "x-php-script",
    exists "x-php-originating-script"
) {
    fileinto "spam";
    fileinto "Mail bomb";
}

คัดลอกแล้ว

3. ตัวกรองที่ย้ายฟอร์มการลงทะเบียนและ/หรือการสมัครสมาชิกที่ส่งเข้ามาไปยังสแปม และนำป้ายกำกับ “Mail bomb” ไปใช้:

require "fileinto";
if allof (
    header :contains "Subject"
        [
            "subscription",
            "mailing",
            "subscribing",
            "confirm",
            "Welcome to",
            "activation",
            "verify",
            "registration",
            "activate",
            "your account",
            "verification",
            "signing up",
            "registering",
            "new account",
            "username and password",
            "registered",
            "welcome",
            "password",
            "account details",
            "verify your"
        ]
) {
    fileinto "spam";
    fileinto "Mail bomb";
}

คัดลอกแล้ว

4. ตัวกรองที่ย้ายข้อความจดหมายข่าวทั้งหมดไปยังโฟลเดอร์สแปมและนำป้ายกำกับ “Mail bomb” ไปใช้ ตัวกรองนี้จะจับคู่อีเมลจากโดเมน “mypapertoday.com” ด้วยเช่นกัน

require "fileinto";
if anyof (
    header :contains "Subject" 
        [
            "Newsletteranmeldung",
            "Newsletterregistrierung",
            "Newsletter",
            "Anmeldung",
            "potwierdzenie",
            "subskrypcji",
            "inscripcin",
            "revista",
            "conferma",
            "inscrizione",
            "validation",
            "willkommen",
            "inscription",
            "account details",
            "Aktivierung",
            "Benutzerkontendetails",
            "bienvenue sur",
            "bienvenido",
            "новом пользователе",
            "benvenuto nel Forum",
            "Hoşgeldiniz",
            "Vítejte na",
            "пожаловать",
            "Bine aţi venit",
            "Üdvözlünk a",
            "fórumon",
            "Witamy na",
            "Velkommen til",
            "Tervetuloa",
            "unirte",
            "Welkom op",
            "activer",
            "Usuario",
            "Välkommen till",
            "Bem vindo",
            "Registrierungsanfrage",
            "注册",
            "подтверждения",
            "регистрацию",
            "Регистрационные",
            "konto",
            "dettagli account",
            "registratie",
            "conta",
            "cuenta",
            "compte",
            "registrazione",
            "contului",
            "konta",
            "aktivoi"
        ],
    address :domain :contains "From" "mypapertoday.com"
) {
    fileinto "Mail bomb";
    fileinto "spam";
}

คัดลอกแล้ว

สำหรับข้อความที่ถูกย้ายไปยังสแปม สามารถตรวจสอบในภายหลังได้อย่างง่ายดาย (โดยการค้นหาป้ายกำกับ “Mail bomb”) เพื่อให้แน่ใจว่าไม่มีข้อความที่ถูกตัวกรองจับไว้โดยผิดพลาด ป้ายกำกับที่ใช้สำหรับตัวกรองนี้สามารถเปลี่ยนได้อย่างง่ายดายเพียงแค่แทนที่คำว่า “Mail Bomb” ในขั้นตอนที่ 2 ถึง 4 ด้านบนด้วยคำที่ต้องการ

โปรดทราบว่าแผนบริการแบบฟรีมีข้อจำกัดเกี่ยวกับจำนวนตัวกรองและป้ายกำกับที่สามารถใช้ได้

สุดท้ายนี้ สามารถอ่านบทความเกี่ยวกับการหลีกเลี่ยงสแปมเพื่อเรียนรู้เพิ่มเติมเกี่ยวกับวิธีป้องกันการโจมตีในลักษณะเดียวกันนี้ในอนาคต

วิธีบรรเทาผลกระทบจากการโจมตีด้วยอีเมลบอมบ์ด้วยตัวกรอง Sieve

ไม่พบสิ่งที่คุณกำลังค้นหาใช่หรือไม่?