Защита от почтовых бомб

Почтовая бомбардировка — это вид онлайн-атаки, при которой злоумышленник отправляет огромное количество электронных писем на определенный адрес или в компьютерную сеть, чтобы переполнить почтовый ящик получателя.

Все более распространенная форма этой атаки заключается в бомбардировке почтового ящика пользователя письмами с подтверждением регистрации.

Proton Mail предлагает фильтрацию спама, чтобы предотвратить попадание спам-сообщений в папку «Входящие». Однако в случае с почтовыми бомбами спам-активность обычно исходит от легитимных форм регистрации, что в некоторых ситуациях может сделать спам-фильтр неэффективным. Для таких случаев вы можете использовать более продвинутый Sieve-фильтр. В этой статье объясняется, как добавить Sieve-фильтр в ваш почтовый ящик.

ВАЖНО: Применение указанных ниже Sieve-фильтров сопряжено с риском ложных срабатываний, из-за которых также могут быть отфильтрованы легитимные сообщения. По этой причине мы рекомендуем оставлять фильтр активным только на время атаки.

Как минимизировать последствия атаки почтовой бомбой с помощью Sieve-фильтра

Войдите в свой аккаунт в веб-версии Proton Mail на странице mail.proton.me и выполните следующие действия:

1. Создайте ярлык, который будет применяться ко всем электронным письмам, определенным как часть атаки почтовой бомбой.

• Перейдите в Настройки -> Папки/Ярлыки.
• Нажмите «ДОБАВИТЬ ЯРЛЫК», создайте ярлык с названием «Mail bomb» и нажмите «Сохранить».

2. Создайте Sieve-фильтр, который будет либо удалять все сообщения, либо отправлять все сообщения в папку «Спам».

• Перейдите в Настройки -> Фильтры и нажмите «ДОБАВИТЬ SIEVE-ФИЛЬТР».
• В поле «Имя» укажите название для своего Sieve-фильтра.
• В поле «Sieve-скрипт» скопируйте и вставьте один из приведенных ниже вариантов кода.

Существует четыре варианта Sieve-фильтра, которые вы можете использовать в зависимости от характеристик получаемых писем и от того, что вы хотите сделать с письмами, перехваченными фильтром:

1. Фильтр, который удаляет сообщения на основании содержимого заголовка, содержащего определенные распространенные ключевые слова. При применении этого фильтра отфильтрованные сообщения никогда не попадут в папку «Входящие», поэтому мы рекомендуем применять Sieve-фильтры только на время атаки:

if anyof (
    header "x-auto-response-suppress" ["OOF", "AutoReply"],
    header "precedence" "bulk",
    header "auto-submitted" "auto-generated",
    exists "form-sub",
    exists "list-unsubscribe",
    exists "x-php-script",
    exists "x-php-originating-script"
) {
    discard;
}

2. Более мягкий вариант первого способа. Вместо удаления сообщений этот фильтр перемещает их в папку «Спам» и присваивает им ярлык «Mail bomb»:

require "fileinto";
if anyof (
    header "x-auto-response-suppress" ["OOF", "AutoReply"],
    header "precedence" "bulk",
    header "auto-submitted" "auto-generated",
    exists "form-sub",
    exists "list-unsubscribe",
    exists "x-php-script",
    exists "x-php-originating-script"
) {
    fileinto "spam";
    fileinto "Mail bomb";
}

3. Фильтр, который перемещает входящие формы регистрации и/или подписки в папку «Спам» и присваивает им ярлык «Mail bomb»:

require "fileinto";
if allof (
    header :contains "Subject"
        [
            "subscription",
            "mailing",
            "subscribing",
            "confirm",
            "Welcome to",
            "activation",
            "verify",
            "registration",
            "activate",
            "your account",
            "verification",
            "signing up",
            "registering",
            "new account",
            "username and password",
            "registered",
            "welcome",
            "password",
            "account details",
            "verify your"
        ]
) {
    fileinto "spam";
    fileinto "Mail bomb";
}

4. Фильтр, который перемещает все сообщения рассылок в папку «Спам» и присваивает им ярлык «Mail bomb». Под этот фильтр также попадут письма с домена «mypapertoday.com».

require "fileinto";
if anyof (
    header :contains "Subject" 
        [
            "Newsletteranmeldung",
            "Newsletterregistrierung",
            "Newsletter",
            "Anmeldung",
            "potwierdzenie",
            "subskrypcji",
            "inscripcin",
            "revista",
            "conferma",
            "inscrizione",
            "validation",
            "willkommen",
            "inscription",
            "account details",
            "Aktivierung",
            "Benutzerkontendetails",
            "bienvenue sur",
            "bienvenido",
            "новом пользователе",
            "benvenuto nel Forum",
            "Hoşgeldiniz",
            "Vítejte na",
            "пожаловать",
            "Bine aţi venit",
            "Üdvözlünk a",
            "fórumon",
            "Witamy na",
            "Velkommen til",
            "Tervetuloa",
            "unirte",
            "Welkom op",
            "activer",
            "Usuario",
            "Välkommen till",
            "Bem vindo",
            "Registrierungsanfrage",
            "注册",
            "подтверждения",
            "регистрацию",
            "Регистрационные",
            "konto",
            "dettagli account",
            "registratie",
            "conta",
            "cuenta",
            "compte",
            "registrazione",
            "contului",
            "konta",
            "aktivoi"
        ],
    address :domain :contains "From" "mypapertoday.com"
) {
    fileinto "Mail bomb";
    fileinto "spam";
}

Вы сможете легко просмотреть перемещенные в «Спам» сообщения позже (выполнив поиск по ярлыку «Mail bomb»), чтобы убедиться, что они не попали под фильтр по ошибке. Ярлык, используемый для этого фильтра, можно легко изменить, просто заменив слово «Mail bomb» на шагах 2–4 выше на любой другой вариант по вашему выбору.

Обратите внимание, что на бесплатных тарифах действуют ограничения на количество используемых фильтров и ярлыков.

Наконец, вы можете прочитать нашу статью о том, как избежать спама, чтобы узнать больше о способах предотвращения подобных атак в будущем.