Mitigación de bombardeos de correo electrónico

Un bombardeo de correo electrónico es un tipo de ataque online en el que el atacante envía una cantidad masiva de correos electrónicos a una dirección o red de ordenadores específica con el fin de saturar la bandeja de entrada del destinatario.

Una forma cada vez más común de este ataque consiste en bombardear el buzón del usuario con correos electrónicos de confirmación de registro.

Proton Mail ofrece filtrado de spam para evitar que los mensajes de spam lleguen a la bandeja de entrada. Sin embargo, en el caso de las bombas de correo electrónico, la actividad de spam suele proceder de formularios de registro legítimos, lo que en algunos casos puede hacer que el filtro de spam sea ineficaz. Para estas situaciones, puedes utilizar un filtro Sieve más avanzado. Este artículo te explicará los pasos para añadir un filtro Sieve a tu bandeja de entrada.

IMPORTANTE: Al aplicar los filtros Sieve descritos a continuación, existe el riesgo de falsos positivos que también filtrarán mensajes legítimos. Por este motivo, recomendamos mantenerlos activos únicamente mientras dure el ataque.

Cómo mitigar una bomba de correo electrónico con un filtro Sieve

Inicia sesión en tu cuenta en la versión web de Proton Mail en mail.proton.me y sigue estos pasos:

1. Crea una etiqueta que se aplicará a todos los correos electrónicos identificados como parte del ataque de bomba de correo.

• Ve a Configuración -> Carpetas/Etiquetas.
• Haz clic en “AÑADIR ETIQUETA”, crea una etiqueta llamada “Mail bomb” y haz clic en “Guardar”.

2. Crea un filtro Sieve que descarte todos los mensajes o los envíe a tu carpeta de Spam.

• Ve a Configuración -> Filtros y haz clic en “AÑADIR FILTRO SIEVE”.
• En el campo “Nombre”, crea un nombre para tu filtro Sieve.
• En el campo “Script Sieve”, copia y pega una de las siguientes opciones de código.

Hay cuatro opciones de filtro Sieve que puedes utilizar, según las características de los correos electrónicos que recibas y lo que quieras hacer con los correos capturados por el filtro:

1. Un filtro que descarta los mensajes en función del contenido del encabezado que contenga ciertas palabras clave comunes. Cuando se aplica este filtro, los mensajes filtrados nunca llegarán a la bandeja de entrada, por lo que sugerimos aplicar los filtros Sieve solo mientras dure el ataque:

if anyof (
    header "x-auto-response-suppress" ["OOF", "AutoReply"],
    header "precedence" "bulk",
    header "auto-submitted" "auto-generated",
    exists "form-sub",
    exists "list-unsubscribe",
    exists "x-php-script",
    exists "x-php-originating-script"
) {
    discard;
}

2. Una variante un poco más suave de la primera opción. En lugar de descartar los mensajes, este filtro los mueve a tu carpeta de Spam y les aplica la etiqueta “Mail bomb”:

require "fileinto";
if anyof (
    header "x-auto-response-suppress" ["OOF", "AutoReply"],
    header "precedence" "bulk",
    header "auto-submitted" "auto-generated",
    exists "form-sub",
    exists "list-unsubscribe",
    exists "x-php-script",
    exists "x-php-originating-script"
) {
    fileinto "spam";
    fileinto "Mail bomb";
}

3. Un filtro que mueve los formularios de registro o suscripción entrantes a Spam y aplica la etiqueta “Mail bomb”:

require "fileinto";
if allof (
    header :contains "Subject"
        [
            "subscription",
            "mailing",
            "subscribing",
            "confirm",
            "Welcome to",
            "activation",
            "verify",
            "registration",
            "activate",
            "your account",
            "verification",
            "signing up",
            "registering",
            "new account",
            "username and password",
            "registered",
            "welcome",
            "password",
            "account details",
            "verify your"
        ]
) {
    fileinto "spam";
    fileinto "Mail bomb";
}

4. Un filtro que mueve todos los mensajes de boletines a tu carpeta de Spam y aplica la etiqueta “Mail bomb”. Este filtro también coincidirá con los correos electrónicos del dominio “mypapertoday.com”.

require "fileinto";
if anyof (
    header :contains "Subject" 
        [
            "Newsletteranmeldung",
            "Newsletterregistrierung",
            "Newsletter",
            "Anmeldung",
            "potwierdzenie",
            "subskrypcji",
            "inscripcin",
            "revista",
            "conferma",
            "inscrizione",
            "validation",
            "willkommen",
            "inscription",
            "account details",
            "Aktivierung",
            "Benutzerkontendetails",
            "bienvenue sur",
            "bienvenido",
            "новом пользователе",
            "benvenuto nel Forum",
            "Hoşgeldiniz",
            "Vítejte na",
            "пожаловать",
            "Bine aţi venit",
            "Üdvözlünk a",
            "fórumon",
            "Witamy na",
            "Velkommen til",
            "Tervetuloa",
            "unirte",
            "Welkom op",
            "activer",
            "Usuario",
            "Välkommen till",
            "Bem vindo",
            "Registrierungsanfrage",
            "注册",
            "подтверждения",
            "регистрацию",
            "Регистрационные",
            "konto",
            "dettagli account",
            "registratie",
            "conta",
            "cuenta",
            "compte",
            "registrazione",
            "contului",
            "konta",
            "aktivoi"
        ],
    address :domain :contains "From" "mypapertoday.com"
) {
    fileinto "Mail bomb";
    fileinto "spam";
}

En el caso de los mensajes movidos a Spam, puedes revisarlos fácilmente más tarde (buscando la etiqueta “Mail bomb”) para asegurarte de que no se hayan filtrado por error. La etiqueta utilizada para este filtro se puede cambiar de forma sencilla con tan solo sustituir la palabra “Mail Bomb” en los pasos 2 a 4 anteriores por la que tú prefieras.

Ten en cuenta que los planes gratuitos tienen limitaciones en la cantidad de filtros y etiquetas que se pueden usar.

Por último, puedes leer nuestro artículo sobre cómo evitar el spam para obtener más información sobre cómo prevenir este tipo de ataques en el futuro.