Mitigasi bom email

Bom email adalah sejenis serangan daring ketika penyerang mengirimkan email dalam jumlah besar ke alamat atau jaringan komputer tertentu untuk membanjiri kotak masuk penerima.

Bentuk serangan yang semakin umum ini terdiri dari pemboman kotak surat pengguna dengan email konfirmasi pendaftaran.

Proton Mail menawarkan filter spam untuk mencegah pesan spam masuk ke kotak masuk. Namun, dalam kasus bom email, aktivitas spam cenderung berasal dari formulir pendaftaran resmi, yang dalam beberapa kasus dapat membuat filter spam tidak efektif. Untuk situasi ini, filter Sieve yang lebih lanjutan dapat digunakan. Artikel ini akan menjelaskan langkah-langkah untuk menambahkan filter Sieve ke kotak masuk.

PENTING: Dengan menerapkan filter Sieve di bawah ini, terdapat risiko positif palsu yang juga akan menyaring pesan sah. Oleh karena itu, disarankan untuk membiarkannya tetap aktif hanya selama durasi serangan berlangsung.

Cara memitigasi bom email dengan filter Sieve

Masuk ke akun di Proton Mail versi web di mail.proton.me dan ikuti langkah-langkah berikut:

1. Buat label yang akan diterapkan ke semua email yang diidentifikasi sebagai bagian dari serangan bom email.

• Buka Pengaturan -> Folder/Label.
• Klik “TAMBAH LABEL”, buat label bernama “Mail bomb” dan klik “Simpan”.

2. Buat filter Sieve yang akan menghapus semua pesan atau mengirim semua pesan ke folder Spam.

• Buka Pengaturan -> Filter dan klik “TAMBAH FILTER SIEVE”.
• Pada kolom “Nama”, buat nama untuk filter Sieve.
• Pada kolom “Skrip Sieve”, salin dan tempel salah satu opsi kode di bawah ini.

Terdapat empat opsi filter Sieve yang dapat digunakan, bergantung pada karakteristik email yang diterima dan tindakan yang ingin dilakukan terhadap email yang tersaring oleh filter:

1. Filter yang menghapus pesan berdasarkan konten header yang mengandung kata kunci umum tertentu. Ketika filter ini diterapkan, pesan yang difilter tidak akan pernah sampai ke Kotak Masuk, itulah sebabnya disarankan untuk menerapkan filter Sieve hanya selama durasi serangan berlangsung:

if anyof (
    header "x-auto-response-suppress" ["OOF", "AutoReply"],
    header "precedence" "bulk",
    header "auto-submitted" "auto-generated",
    exists "form-sub",
    exists "list-unsubscribe",
    exists "x-php-script",
    exists "x-php-originating-script"
) {
    discard;
}

2. Varian yang sedikit lebih ringan dari opsi pertama. Alih-alih menghapus pesan, filter ini memindahkannya ke folder Spam dan menerapkan label “Mail bomb”:

require "fileinto";
if anyof (
    header "x-auto-response-suppress" ["OOF", "AutoReply"],
    header "precedence" "bulk",
    header "auto-submitted" "auto-generated",
    exists "form-sub",
    exists "list-unsubscribe",
    exists "x-php-script",
    exists "x-php-originating-script"
) {
    fileinto "spam";
    fileinto "Mail bomb";
}

3. Filter yang memindahkan formulir pendaftaran dan/atau langganan yang masuk ke Spam dan menerapkan label “Mail bomb”:

require "fileinto";
if allof (
    header :contains "Subject"
        [
            "subscription",
            "mailing",
            "subscribing",
            "confirm",
            "Welcome to",
            "activation",
            "verify",
            "registration",
            "activate",
            "your account",
            "verification",
            "signing up",
            "registering",
            "new account",
            "username and password",
            "registered",
            "welcome",
            "password",
            "account details",
            "verify your"
        ]
) {
    fileinto "spam";
    fileinto "Mail bomb";
}

4. Filter yang memindahkan semua pesan buletin ke folder Spam dan menerapkan label “Mail bomb”. Filter ini juga akan mencocokkan email dari domain “mypapertoday.com”.

require "fileinto";
if anyof (
    header :contains "Subject" 
        [
            "Newsletteranmeldung",
            "Newsletterregistrierung",
            "Newsletter",
            "Anmeldung",
            "potwierdzenie",
            "subskrypcji",
            "inscripcin",
            "revista",
            "conferma",
            "inscrizione",
            "validation",
            "willkommen",
            "inscription",
            "account details",
            "Aktivierung",
            "Benutzerkontendetails",
            "bienvenue sur",
            "bienvenido",
            "новом пользователе",
            "benvenuto nel Forum",
            "Hoşgeldiniz",
            "Vítejte na",
            "пожаловать",
            "Bine aţi venit",
            "Üdvözlünk a",
            "fórumon",
            "Witamy na",
            "Velkommen til",
            "Tervetuloa",
            "unirte",
            "Welkom op",
            "activer",
            "Usuario",
            "Välkommen till",
            "Bem vindo",
            "Registrierungsanfrage",
            "注册",
            "подтверждения",
            "регистрацию",
            "Регистрационные",
            "konto",
            "dettagli account",
            "registratie",
            "conta",
            "cuenta",
            "compte",
            "registrazione",
            "contului",
            "konta",
            "aktivoi"
        ],
    address :domain :contains "From" "mypapertoday.com"
) {
    fileinto "Mail bomb";
    fileinto "spam";
}

Untuk pesan yang dipindahkan ke Spam, pesan tersebut dapat ditinjau kembali dengan mudah nanti (dengan mencari label “Mail bomb”) untuk memastikan pesan tidak tersaring secara tidak sengaja. Label yang digunakan untuk filter ini dapat diubah dengan mudah hanya dengan mengganti kata “Mail bomb” pada langkah 2 sampai 4 di atas dengan kata apa pun yang diinginkan.

Harap dicatat bahwa paket gratis memiliki batasan jumlah filter dan label yang dapat digunakan.

Terakhir, silakan baca artikel tentang menghindari spam untuk mempelajari lebih lanjut tentang cara mencegah jenis serangan serupa di masa mendatang.