Mitigering av e-postbomber

En e-postbomb är en form av onlineattack där angriparen skickar en enorm mängd e-postmeddelanden till en specifik adress eller ett datornätverk i syfte att överbelasta mottagarens inkorg.

En allt vanligare form av denna attack består av att bombardera användarens brevlåda med e-postbekräftelser för registrering.

Proton Mail erbjuder skräppostfiltrering för att förhindra att skräppostmeddelanden når inkorgen. I fallet med e-postbomber tenderar dock skräppostaktiviteten att komma från legitima registreringsformulär, vilket i vissa fall kan göra skräppostfiltret ineffektivt. För dessa situationer kan du använda ett mer avancerat Sieve-filter. Den här artikeln förklarar stegen för att lägga till ett Sieve-filter i din inkorg.

VIKTIGT: Genom att tillämpa Sieve-filtren nedan finns det en risk för falska positiva som även kommer att filtrera bort legitima meddelanden. Av denna anledning rekommenderar vi att du endast håller det aktivt så länge attacken pågår.

Så mildrar du en e-postbomb med ett Sieve-filter

Logga in på ditt konto i webbversionen av Proton Mail på mail.proton.me och följ dessa steg:

1. Skapa en etikett som ska tillämpas på alla e-postmeddelanden som identifieras som en del av e-postbombsattacken.

• Gå till Inställningar -> Mappar/Etiketter.
• Klicka på ”LÄGG TILL ETIKETT”, skapa en etikett med namnet ”E-postbomb” och klicka på ”Spara”.

2. Skapa ett Sieve-filter som antingen kastar alla meddelanden eller skickar alla meddelanden till din skräppostmapp.

• Gå till Inställningar -> Filter och klicka på ”LÄGG TILL SIEVE-FILTER”.
• I fältet ”Namn” skapar du ett namn för ditt Sieve-filter.
• I fältet ”Sieve-skript” kopierar och klistrar du in ett av kodalternativen nedan.

Det finns fyra alternativ för Sieve-filter som du kan använda, beroende på egenskaperna hos de e-postmeddelanden du tar emot och vad du vill göra med de e-postmeddelanden som fångas upp av filtret:

1. Ett filter som kastar meddelandena baserat på rubrikens innehåll som innehåller vissa vanliga nyckelord. När detta filter tillämpas kommer de filtrerade meddelandena aldrig att nå inkorgen, vilket är anledningen till att vi föreslår att Sieve-filter endast tillämpas så länge attacken pågår:

if anyof (
    header "x-auto-response-suppress" ["OOF", "AutoReply"],
    header "precedence" "bulk",
    header "auto-submitted" "auto-generated",
    exists "form-sub",
    exists "list-unsubscribe",
    exists "x-php-script",
    exists "x-php-originating-script"
) {
    discard;
}

2. En något mildare variant av det första alternativet. Istället för att kasta meddelandena flyttar detta filter dem till din skräppostmapp och tillämpar etiketten ”E-postbomb”:

require "fileinto";
if anyof (
    header "x-auto-response-suppress" ["OOF", "AutoReply"],
    header "precedence" "bulk",
    header "auto-submitted" "auto-generated",
    exists "form-sub",
    exists "list-unsubscribe",
    exists "x-php-script",
    exists "x-php-originating-script"
) {
    fileinto "spam";
    fileinto "Mail bomb";
}

3. Ett filter som flyttar inkommande registrerings- och/eller prenumerationsformulär till skräppost och tillämpar etiketten ”E-postbomb”:

require "fileinto";
if allof (
    header :contains "Subject"
        [
            "subscription",
            "mailing",
            "subscribing",
            "confirm",
            "Welcome to",
            "activation",
            "verify",
            "registration",
            "activate",
            "your account",
            "verification",
            "signing up",
            "registering",
            "new account",
            "username and password",
            "registered",
            "welcome",
            "password",
            "account details",
            "verify your"
        ]
) {
    fileinto "spam";
    fileinto "Mail bomb";
}

4. Ett filter som flyttar alla nyhetsbrev till din skräppostmapp och tillämpar etiketten ”E-postbomb”. Detta filter kommer också att matcha e-postmeddelanden från domänen ”mypapertoday.com”.

require "fileinto";
if anyof (
    header :contains "Subject" 
        [
            "Newsletteranmeldung",
            "Newsletterregistrierung",
            "Newsletter",
            "Anmeldung",
            "potwierdzenie",
            "subskrypcji",
            "inscripcin",
            "revista",
            "conferma",
            "inscrizione",
            "validation",
            "willkommen",
            "inscription",
            "account details",
            "Aktivierung",
            "Benutzerkontendetails",
            "bienvenue sur",
            "bienvenido",
            "новом пользователе",
            "benvenuto nel Forum",
            "Hoşgeldiniz",
            "Vítejte na",
            "пожаловать",
            "Bine aţi venit",
            "Üdvözlünk a",
            "fórumon",
            "Witamy na",
            "Velkommen til",
            "Tervetuloa",
            "unirte",
            "Welkom op",
            "activer",
            "Usuario",
            "Välkommen till",
            "Bem vindo",
            "Registrierungsanfrage",
            "注册",
            "подтверждения",
            "регистрацию",
            "Регистрационные",
            "konto",
            "dettagli account",
            "registratie",
            "conta",
            "cuenta",
            "compte",
            "registrazione",
            "contului",
            "konta",
            "aktivoi"
        ],
    address :domain :contains "From" "mypapertoday.com"
) {
    fileinto "Mail bomb";
    fileinto "spam";
}

När det gäller meddelanden som flyttats till skräppost kan du enkelt granska dem senare (genom att söka efter etiketten ”E-postbomb”) för att säkerställa att meddelanden inte har fastnat i filtret av misstag. Etiketten som används för detta filter kan enkelt ändras genom att helt enkelt ersätta ordet ”E-postbomb” i stegen 2 till 4 ovan med vad du än föredrar.

Observera att gratispaket har begränsningar för hur många filter och etiketter som kan användas.

Slutligen kan du läsa vår artikel om att undvika skräppost för att lära dig mer om hur du förhindrar liknande typer av attacker i framtiden.