Ograniczanie skutków bombardowania wiadomościami e-mail

Bombardowanie wiadomościami (email bomb) to rodzaj ataku online, w którym atakujący wysyła masową liczbę wiadomości na określony adres lub do sieci komputerowej w celu przepełnienia skrzynki odbiorczej odbiorcy.

Coraz powszechniejsza forma tego ataku polega na zasypywaniu skrzynki pocztowej użytkownika wiadomościami z potwierdzeniem rejestracji.

Proton Mail oferuje filtry antyspamowe, które zapobiegają trafianiu spamu do skrzynki odbiorczej. Jednak w przypadku bomb e-mailowych spamowanie często pochodzi z legalnych formularzy rejestracyjnych, co w niektórych przypadkach może sprawić, że filtr antyspamowy będzie nieskuteczny. W takich sytuacjach możesz użyć bardziej zaawansowanego filtra Sieve. Ten artykuł wyjaśni kroki potrzebne do dodania filtra Sieve do Twojej skrzynki odbiorczej.

WAŻNE: Zastosowanie poniższych filtrów Sieve wiąże się z ryzykiem błędnego zaklasyfikowania wiadomości jako spam (false positive), co spowoduje odfiltrowanie również pożądanych wiadomości. Z tego powodu zalecamy, aby filtr pozostawał aktywny tylko na czas trwania ataku.

Jak złagodzić skutki bomby e-mailowej za pomocą filtra Sieve

Zaloguj się na swoje konto w wersji przeglądarkowej Proton Mail pod adresem mail.proton.me i wykonaj następujące kroki:

1. Utwórz etykietę, która będzie stosowana do wszystkich wiadomości zidentyfikowanych jako część ataku typu bomba e-mailowa.

• Przejdź do: Ustawienia -> Foldery i etykiety.
• Kliknij „DODAJ ETYKIETĘ”, utwórz etykietę o nazwie „Mail bomb” i kliknij „Zapisz”.

2. Utwórz filtr Sieve, który odrzuci wszystkie wiadomości lub wyśle je wszystkie do folderu Spam.

• Przejdź do: Ustawienia -> Filtry i kliknij „DODAJ FILTR SIEVE”.
• W polu „Nazwa” utwórz nazwę dla swojego filtra Sieve.
• W polu „Skrypt Sieve” skopiuj i wklej jedną z poniższych opcji kodu.

Możesz użyć czterech opcji filtrów Sieve, w zależności od charakterystyki otrzymywanych wiadomości e-mail oraz tego, co chcesz zrobić z wiadomościami przechwyconymi przez filtr:

1. Filtr, który odrzuca wiadomości na podstawie zawartości nagłówka zawierającej określone popularne słowa kluczowe. Po zastosowaniu tego filtra odfiltrowane wiadomości nigdy nie trafią do skrzynki odbiorczej, dlatego sugerujemy stosowanie filtrów Sieve tylko na czas trwania ataku:

if anyof (
    header "x-auto-response-suppress" ["OOF", "AutoReply"],
    header "precedence" "bulk",
    header "auto-submitted" "auto-generated",
    exists "form-sub",
    exists "list-unsubscribe",
    exists "x-php-script",
    exists "x-php-originating-script"
) {
    discard;
}

2. Nieco łagodniejszy wariant pierwszej opcji. Zamiast odrzucać wiadomości, ten filtr przenosi je do folderu Spam i stosuje etykietę „Mail bomb”:

require "fileinto";
if anyof (
    header "x-auto-response-suppress" ["OOF", "AutoReply"],
    header "precedence" "bulk",
    header "auto-submitted" "auto-generated",
    exists "form-sub",
    exists "list-unsubscribe",
    exists "x-php-script",
    exists "x-php-originating-script"
) {
    fileinto "spam";
    fileinto "Mail bomb";
}

3. Filtr, który przenosi przychodzące formularze rejestracji i/lub subskrypcji do folderu Spam i stosuje etykietę „Mail bomb”:

require "fileinto";
if allof (
    header :contains "Subject"
        [
            "subscription",
            "mailing",
            "subscribing",
            "confirm",
            "Welcome to",
            "activation",
            "verify",
            "registration",
            "activate",
            "your account",
            "verification",
            "signing up",
            "registering",
            "new account",
            "username and password",
            "registered",
            "welcome",
            "password",
            "account details",
            "verify your"
        ]
) {
    fileinto "spam";
    fileinto "Mail bomb";
}

4. Filtr, który przenosi wszystkie newslettery do folderu Spam i stosuje etykietę „Mail bomb”. Ten filtr dopasuje również wiadomości z domeny „mypapertoday.com”.

require "fileinto";
if anyof (
    header :contains "Subject" 
        [
            "Newsletteranmeldung",
            "Newsletterregistrierung",
            "Newsletter",
            "Anmeldung",
            "potwierdzenie",
            "subskrypcji",
            "inscripcin",
            "revista",
            "conferma",
            "inscrizione",
            "validation",
            "willkommen",
            "inscription",
            "account details",
            "Aktivierung",
            "Benutzerkontendetails",
            "bienvenue sur",
            "bienvenido",
            "новом пользователе",
            "benvenuto nel Forum",
            "Hoşgeldiniz",
            "Vítejte na",
            "пожаловать",
            "Bine aţi venit",
            "Üdvözlünk a",
            "fórumon",
            "Witamy na",
            "Velkommen til",
            "Tervetuloa",
            "unirte",
            "Welkom op",
            "activer",
            "Usuario",
            "Välkommen till",
            "Bem vindo",
            "Registrierungsanfrage",
            "注册",
            "подтверждения",
            "регистрацию",
            "Регистрационные",
            "konto",
            "dettagli account",
            "registratie",
            "conta",
            "cuenta",
            "compte",
            "registrazione",
            "contului",
            "konta",
            "aktivoi"
        ],
    address :domain :contains "From" "mypapertoday.com"
) {
    fileinto "Mail bomb";
    fileinto "spam";
}

Wiadomości przeniesione do folderu Spam możesz później łatwo przejrzeć (wyszukując etykietę „Mail bomb”), aby upewnić się, że żadna wiadomość nie została przechwycona przez filtr przez pomyłkę. Etykietę używaną w tym filtrze można łatwo zmienić, zastępując po prostu słowa „Mail bomb” w powyższych krokach od 2 do 4 dowolną inną nazwą.

Pamiętaj, że darmowe plany mają ograniczenia dotyczące liczby filtrów i etykiet, których można używać.

Na koniec możesz przeczytać nasz artykuł o unikaniu spamu, aby dowiedzieć się więcej o tym, jak zapobiegać podobnym atakom w przyszłości.