Mitigación de bombardeo de correo electrónico

Una bomba de correo electrónico es un tipo de ataque en línea en el que el atacante envía una cantidad masiva de correos electrónicos a una dirección o red de computadora específica para saturar la bandeja de entrada del destinatario.

Una forma cada vez más común de este ataque consiste en bombardear el buzón del usuario con correos electrónicos de confirmación de registro.

Proton Mail ofrece filtros de spam para evitar que los mensajes de spam lleguen a la bandeja de entrada. Sin embargo, en el caso de las bombas de correo electrónico, la actividad de spam suele provenir de formularios de registro legítimos, lo que en algunos casos puede hacer que el filtro de spam sea ineficaz. Para estas situaciones, puede utilizar un filtro Sieve más avanzado. Este artículo le explicará los pasos para agregar un filtro Sieve a su bandeja de entrada.

IMPORTANTE: Al aplicar los siguientes filtros Sieve, existe el riesgo de falsos positivos que también filtrarán mensajes legítimos. Por este motivo, le recomendamos mantenerlos activos solo durante la duración del ataque.

Cómo mitigar una bomba de correo electrónico con un filtro Sieve

Inicie sesión en su cuenta en la versión web de Proton Mail en mail.proton.me y siga estos pasos:

1. Cree una etiqueta que se aplicará a todos los correos electrónicos identificados como parte del ataque de bomba de correo.

• Vaya a Ajustes -> Carpetas/Etiquetas.
• Haga clic en “AGREGAR ETIQUETA”, cree una etiqueta llamada “Mail bomb” y haga clic en “Guardar”.

2. Cree un filtro Sieve que descarte todos los mensajes o los envíe a su carpeta de Spam.

• Vaya a Ajustes -> Filtros y haga clic en “AGREGAR FILTRO SIEVE”.
• En el campo “Nombre”, cree un nombre para su filtro Sieve.
• En el campo “Script de Sieve”, copie y pegue una de las siguientes opciones de código.

Existen cuatro opciones de filtros Sieve que puede utilizar, según las características de los correos electrónicos que esté recibiendo y lo que quiera hacer con los correos capturados por el filtro:

1. Un filtro que descarta los mensajes según el contenido del encabezado que contenga ciertas palabras clave comunes. Cuando se aplica este filtro, los mensajes filtrados nunca llegarán a la bandeja de entrada, por lo que sugerimos aplicar los filtros Sieve únicamente durante la duración del ataque:

if anyof (
    header "x-auto-response-suppress" ["OOF", "AutoReply"],
    header "precedence" "bulk",
    header "auto-submitted" "auto-generated",
    exists "form-sub",
    exists "list-unsubscribe",
    exists "x-php-script",
    exists "x-php-originating-script"
) {
    discard;
}

2. Una variante un poco más suave de la primera opción. En lugar de descartar los mensajes, este filtro los mueve a su carpeta de Spam y les aplica la etiqueta “Mail bomb”:

require "fileinto";
if anyof (
    header "x-auto-response-suppress" ["OOF", "AutoReply"],
    header "precedence" "bulk",
    header "auto-submitted" "auto-generated",
    exists "form-sub",
    exists "list-unsubscribe",
    exists "x-php-script",
    exists "x-php-originating-script"
) {
    fileinto "spam";
    fileinto "Mail bomb";
}

3. Un filtro que mueve los formularios de registro o suscripción entrantes a Spam y aplica la etiqueta “Mail bomb”:

require "fileinto";
if allof (
    header :contains "Subject"
        [
            "subscription",
            "mailing",
            "subscribing",
            "confirm",
            "Welcome to",
            "activation",
            "verify",
            "registration",
            "activate",
            "your account",
            "verification",
            "signing up",
            "registering",
            "new account",
            "username and password",
            "registered",
            "welcome",
            "password",
            "account details",
            "verify your"
        ]
) {
    fileinto "spam";
    fileinto "Mail bomb";
}

4. Un filtro que mueve todos los mensajes de boletines informativos a su carpeta de Spam y aplica la etiqueta “Mail bomb”. Este filtro también coincidirá con los correos electrónicos del dominio “mypapertoday.com”.

require "fileinto";
if anyof (
    header :contains "Subject" 
        [
            "Newsletteranmeldung",
            "Newsletterregistrierung",
            "Newsletter",
            "Anmeldung",
            "potwierdzenie",
            "subskrypcji",
            "inscripcin",
            "revista",
            "conferma",
            "inscrizione",
            "validation",
            "willkommen",
            "inscription",
            "account details",
            "Aktivierung",
            "Benutzerkontendetails",
            "bienvenue sur",
            "bienvenido",
            "новом пользователе",
            "benvenuto nel Forum",
            "Hoşgeldiniz",
            "Vítejte na",
            "пожаловать",
            "Bine aţi venit",
            "Üdvözlünk a",
            "fórumon",
            "Witamy na",
            "Velkommen til",
            "Tervetuloa",
            "unirte",
            "Welkom op",
            "activer",
            "Usuario",
            "Välkommen till",
            "Bem vindo",
            "Registrierungsanfrage",
            "注册",
            "подтверждения",
            "регистрацию",
            "Регистрационные",
            "konto",
            "dettagli account",
            "registratie",
            "conta",
            "cuenta",
            "compte",
            "registrazione",
            "contului",
            "konta",
            "aktivoi"
        ],
    address :domain :contains "From" "mypapertoday.com"
) {
    fileinto "Mail bomb";
    fileinto "spam";
}

En el caso de los mensajes movidos a Spam, puede revisarlos fácilmente más tarde (buscando la etiqueta “Mail bomb”) para asegurarse de que no se hayan filtrado por error. La etiqueta utilizada para este filtro se puede cambiar fácilmente con solo reemplazar la palabra “Mail bomb” en los pasos 2 al 4 anteriores por la que usted prefiera.

Tenga en cuenta que los planes gratuitos tienen limitaciones en la cantidad de filtros y etiquetas que se pueden utilizar.

Por último, puede leer nuestro artículo sobre cómo evitar el spam para obtener más información sobre cómo prevenir tipos de ataques similares en el futuro.